一、什么是PendSV
PendSV是可悬起反常，假设咱们把它装备最低优先级，那么假设一起有多个反常被触发，它会在其他反常履行结束后再履行，并且任何反常都能够中止它。更具体的内容在《Cortex-M3 威望攻略》里有介绍，下面我摘录了一段。
OS 能够利用它“延期履行”一个反常——直到其它重要的使命完结后才履举动 作。悬起 PendSV 的办法是：手艺往 NVIC的 PendSV悬起寄存器中写 1。悬起后，假设优先级不行 高，则将延期等候履行。
PendSV的典型运用场合是在上下文切换时(在不同使命之间切换)。例如，一个体系中有两个安排妥当的使命，上下文切换被触发的场合能够是：
1、履行一个体系调用
2、体系滴答定时器(SYSTICK)中止，(轮转调度中需求)
让咱们举个简略的例子来辅佐了解。假设有这么一个体系，里边有两个安排妥当的使命，并且经过SysTick反常发动上下文切换。但若在产生 SysTick 反常时正在呼应一个中止，则 SysTick反常会抢占其 ISR。在这种情况下，OS是不能履行上下文切换的，不然将使中止恳求被推迟，并且在实在体系中推迟时间还往往不行预知——任何有一丁点实时要求的体系都决不能忍受这 种事。因而，在 CM3 中也是禁止没商量——假设 OS 在某中止活泼时测验切入线程形式，将冒犯用法fault反常。
为处理此问题，前期的 OS 大多会检测当时是否有中止在活泼中，只要在无任何中止需求呼应 时，才履行上下文切换(切换期间无法呼应中止)。但是，这种办法的坏处在于，它能够把使命切 换动作推迟好久(由于假设抢占了 IRQ，则本次 SysTick在履行后不得作上下文切换，只能等候下 一次SysTick反常)，尤其是当某中止源的频率和SysTick反常的频率比较挨近时，会产生“共振”， 使上下文切换迟迟不能进行。现在好了，PendSV来完美处理这个问题了。PendSV反常会主动推迟上下文切换的恳求，直到 其它的 ISR都完结了处理后才放行。为完结这个机制，需求把 PendSV编程为最低优先级的反常。假设 OS检测到某 IRQ正在活动并且被 SysTick抢占，它将悬起一个 PendSV反常，以便延期履行 上下文切换。
运用 PendSV 操控上下文切换个中事情的流水账记载如下：
1. 使命 A呼叫 SVC来恳求使命切换(例如，等候某些作业完结)
2. OS接收到恳求，做好上下文切换的预备，并且悬起一个 PendSV反常。
3. 当 CPU退出 SVC后，它当即进入 PendSV，然后履行上下文切换。
4. 当 PendSV履行结束后，将回来到使命 B，一起进入线程形式。
5. 产生了一个中止，并且中止服务程序开端履行
6. 在 ISR履行过程中，产生 SysTick反常，并且抢占了该 ISR。
7. OS履行必要的操作，然后悬起 PendSV反常以作好上下文切换的预备。
8. 当 SysTick退出后，回到从前被抢占的 ISR中，ISR持续履行
9. ISR履行结束并退出后，PendSV服务例程开端履行，并且在里边履行上下文切换
10. 当 PendSV履行结束后，回到使命 A，一起体系再次进入线程形式。
咱们在uCOS的PendSV的处理代码中能够看到：
OS_CPU_PendSVHandler
CPSID I ; 关中止
;保存上文
;…………………..
;切换下文
CPSIE I ;开中止
BX LR ;反常回来
它在反常一开端就封闭了中端，结束时敞开中止，中心的代码为临界区代码，即不行被中止的操作。PendSV反常是使命切换的仓库部分的中心，由他来完结上下文切换。PendSV的操作也很简略，主要有设置优先级和触发反常两部分：
NVIC_INT_CTRL EQU 0xE000ED04 ; 中止操控寄存器
NVIC_SYSPRI14 EQU 0xE000ED22 ; 体系优先级寄存器(优先级14).
NVIC_PENDSV_PRI EQU 0xFF ; PendSV优先级(最低). NVIC_PENDSVSET EQU 0x10000000 ; PendSV触发值
; 设置PendSV的反常中止优先级
LDR R0, =NVIC_SYSPRI14
LDR R1, =NVIC_PENDSV_PRI
STRB R1, [R0] ; 触发PendSV反常
LDR R0, =NVIC_INT_CTRL
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]
二、仓库操作
Cortex M4有两个仓库寄存器，主仓库指针(MSP)与进程仓库指针(PSP)，并且任一时间只能运用其间的一个。MSP为复位后缺省运用的仓库指针，反常永久运用MSP，假设手动敞开PSP，那么线程运用PSP，不然也运用MSP。怎样敞开PSP?
MSR PSP, R0 ; Load PSP with new process SP
ORR LR, LR, #0x04 ; Ensure exception return uses process stack
很简单就看出来了，置LR的位2为1，那么反常回来后，线程运用PSP。
写OS首要要将内存分配搞理解，单片机内存原本就很小，所以咱们当然要锱铢必较一下。在OS运转之前，咱们首要要初始化MSP和PSP，OS_CPU_ExceptStkBase是外部变量，假设咱们给主仓库分配1KB(256*4)的内存即OS_CPU_ExceptStk[256],则OS_CPU_ExceptStkBase=&OS_CPU_ExceptStk[256-1]。
EXTERN OS_CPU_ExceptStkBase
;PSP清零，作为初次上下文切换的标志
MOVS R0, #0
MSR PSP, R0
;将MSP设为咱们为其分配的内存地址
LDR R0, =OS_CPU_ExceptStkBase
LDR R1, [R0]
MSR MSP, R1
然后便是PendSV上下文切换中的仓库操作了，假设不运用FPU，则进入反常主动压栈xPSR，PC，LR，R12，R0-R3，咱们还要把R4-R11入栈。假设敞开了FPU，主动压栈的寄存器还有S0-S15，还需吧S16-S31压栈。
MRS R0, PSP
SUBS R0, R0, #0x20 ;压入R4-R11
STM R0, {R4-R11}
LDR R1, =Cur_TCB_Point ;当时使命的指针
LDR R1, [R1]
STR R0, [R1] ; 更新使命仓库指针
出栈相似，但要留意次序
LDR R1, =TCB_Point ;要切换的使命指针
LDR R2, [R1]
LDR R0, [R2] ; R0为要切换的使命仓库地址
LDM R0, {R4-R11} ; 弹出R4-R11
ADDS R0, R0, #0x20
MSR PSP, R0 ;更新PSP
三、OS实战
新建os_port.asm文件，内容如下：
NVIC_INT_CTRL EQU 0xE000ED04 ; Interrupt control state register.
NVIC_SYSPRI14 EQU 0xE000ED22 ; System priority register (priority 14).
NVIC_PENDSV_PRI EQU 0xFF ; PendSV priority value (lowest).
NVIC_PENDSVSET EQU 0x10000000 ; Value to trigger PendSV exception.
RSEG CODE:CODE:NOROOT(2)
THUMB
EXTERN g_OS_CPU_ExceptStkBase
EXTERN g_OS_Tcb_CurP
EXTERN g_OS_Tcb_HighRdyP
PUBLIC OSStart_Asm
PUBLIC PendSV_Handler
PUBLIC OSCtxSw
OSCtxSw
LDR R0, =NVIC_INT_CTRL
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]
BX LR ; Enable interrupts at processor level
OSStart_Asm
LDR R0, =NVIC_SYSPRI14 ; Set the PendSV exception priority
LDR R1, =NVIC_PENDSV_PRI
STRB R1, [R0]
MOVS R0, #0 ; Set the PSP to 0 for initial context switch call
MSR PSP, R0
LDR R0, =g_OS_CPU_ExceptStkBase ; Initialize the MSP to the OS_CPU_ExceptStkBase
LDR R1, [R0]
MSR MSP, R1
LDR R0, =NVIC_INT_CTRL ; Trigger the PendSV exception (causes context switch)
LDR R1, =NVIC_PENDSVSET
STR R1, [R0]
CPSIE I ; Enable interrupts at processor level
OSStartHang
B OSStartHang ; Should never get here
PendSV_Handler
CPSID I ; Prevent interruption during context switch
MRS R0, PSP ; PSP is process stack pointer
CBZ R0, OS_CPU_PendSVHandler_nosave ; Skip register save the first time
SUBS R0, R0, #0x20 ; Save remaining regs r4-11 on process stack
STM R0, {R4-R11}
LDR R1, =g_OS_Tcb_CurP ; OSTCBCur->OSTCBStkPtr = SP;
LDR R1, [R1]
STR R0, [R1] ; R0 is SP of process being switched out
; At this point, entire context of process has been saved
OS_CPU_PendSVHandler_nosave
LDR R0, =g_OS_Tcb_CurP ; OSTCBCur = OSTCBHighRdy;
LDR R1, =g_OS_Tcb_HighRdyP
LDR R2, [R1]
STR R2, [R0]
LDR R0, [R2] ; R0 is new process SP; SP = OSTCBHighRdy->OSTCBStkPtr;
LDM R0, {R4-R11} ; Restore r4-11 from new process stack
ADDS R0, R0, #0x20
MSR PSP, R0 ; Load PSP with new process SP
ORR LR, LR, #0x04 ; Ensure exception return uses process stack
CPSIE I
BX LR ; Exception return will restore remaining context
END
main.c内容如下：
#include "stdio.h"
#define OS_EXCEPT_STK_SIZE 1024
#define TASK_1_STK_SIZE 1024
#define TASK_2_STK_SIZE 1024
typedef unsigned int OS_STK;
typedef void (*OS_TASK)(void);
typedef struct OS_TCB
{
OS_STK *StkAddr;
}OS_TCB,*OS_TCBP;
OS_TCBP g_OS_Tcb_CurP;
OS_TCBP g_OS_Tcb_HighRdyP;
static OS_STK OS_CPU_ExceptStk[OS_EXCEPT_STK_SIZE];
OS_STK *g_OS_CPU_ExceptStkBase;
static OS_TCB TCB_1;
static OS_TCB TCB_2;
static OS_STK TASK_1_STK[TASK_1_STK_SIZE];
static OS_STK TASK_2_STK[TASK_2_STK_SIZE];
extern void OSStart_Asm(void);
extern void OSCtxSw(void);
void Task_Switch()
{
if(g_OS_Tcb_CurP == &TCB_1)
g_OS_Tcb_HighRdyP=&TCB_2;
else
g_OS_Tcb_HighRdyP=&TCB_1;
OSCtxSw();
}
void task_1()
{
printf("Task 1 Running!!!\n");
Task_Switch();
printf("Task 1 Running!!!\n");
Task_Switch();
}
void task_2()
{
printf("Task 2 Running!!!\n");
Task_Switch();
printf("Task 2 Running!!!\n");
Task_Switch();
}
void Task_End(void)
{
printf("Task End\n");
while(1)
{}
}
void Task_Create(OS_TCB *tcb,OS_TASK task,OS_STK *stk)
{
OS_STK *p_stk;
p_stk = stk;
p_stk = (OS_STK *)((OS_STK)(p_stk) & 0xFFFFFFF8u);
*(–p_stk) = (OS_STK)0x01000000uL; //xPSR
*(–p_stk) = (OS_STK)task; // Entry Point
*(–p_stk) = (OS_STK)Task_End; // R14 (LR)
*(–p_stk) = (OS_STK)0x12121212uL; // R12
*(–p_stk) = (OS_STK)0x03030303uL; // R3
*(–p_stk) = (OS_STK)0x02020202uL; // R2
*(–p_stk) = (OS_STK)0x01010101uL; // R1
*(–p_stk) = (OS_STK)0x00000000u; // R0
*(–p_stk) = (OS_STK)0x11111111uL; // R11
*(–p_stk) = (OS_STK)0x10101010uL; // R10
*(–p_stk) = (OS_STK)0x09090909uL; // R9
*(–p_stk) = (OS_STK)0x08080808uL; // R8
*(–p_stk) = (OS_STK)0x07070707uL; // R7
*(–p_stk) = (OS_STK)0x06060606uL; // R6
*(–p_stk) = (OS_STK)0x05050505uL; // R5
*(–p_stk) = (OS_STK)0x04040404uL; // R4
tcb->StkAddr=p_stk;
}
int main()
{
g_OS_CPU_ExceptStkBase = OS_CPU_ExceptStk + OS_EXCEPT_STK_SIZE – 1;
Task_Create(&TCB_1,task_1,&TASK_1_STK[TASK_1_STK_SIZE-1]);
Task_Create(&TCB_2,task_2,&TASK_2_STK[TASK_1_STK_SIZE-1]);
g_OS_Tcb_HighRdyP=&TCB_1;
OSStart_Asm();
return 0;
}
编译下载并调试：
在此处设置断点
此刻寄存器的值，能够看到R4-R11正是咱们给的值，单步运转几回，能够看到进入了咱们的使命task_1或task_2，使命里打印信息，然后调用Task_Switch进行切换，OSCtxSw触发PendSV反常。
IO输出如下：
至此咱们成功完结了运用PenSV进行两个使命的相互切换。之后，咱们运用运用SysTick完结比较完好的多使命切换。
